Usen este codigo para obtener el codigo de fuente de una pagina web:
Con control ocx:
**Nota: Deben agregar la referencia Microsoft XML v3.0

Código:

Function FuenteWeb(strURL As String) As String
 Dim xml As MSXML2.XMLHTTP30
 Set xml = New MSXML2.XMLHTTP30
 xml.Open "GET", strURL, False
 xml.send
 FuenteWeb = xml.responseText
End Function

y se usa asi:

Código:

Text1.Text = FuenteWeb("http://www.google.cl")

Sin OCX, sino un dll que viene por defecto en casi todos los equipos:
en un modulo:

Código:

Option Explicit
Public Declare Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" (ByVal sAgent As String, ByVal lAccessType As Long, ByVal sProxyName As String, ByVal sProxyBypass As String, ByVal lFlags As Long) As Long
Public Declare Function InternetOpenUrl Lib "wininet.dll" Alias "InternetOpenUrlA" (ByVal hInternetSession As Long, ByVal sURL As String, ByVal sHeaders As String, ByVal lHeadersLength As Long, ByVal lFlags As Long, ByVal lContext As Long) As Long
Public Declare Function InternetReadFile Lib "wininet.dll" (ByVal hFile As Long, ByVal sBuffer As String, ByVal lNumBytesToRead As Long, lNumberOfBytesRead As Long) As Integer
Public Declare Function InternetCloseHandle Lib "wininet.dll" (ByVal hInet As Long) As Integer

Public Const IF_FROM_CACHE = &H1000000
Public Const IF_MAKE_PERSISTENT = &H2000000
Public Const IF_NO_CACHE_WRITE = &H4000000
 
Private Const BUFFER_LEN = 256


Public Function GetUrlSource(sURL As String) As String
 Dim sBuffer As String * BUFFER_LEN, iResult As Integer, sData As String
 Dim hInternet As Long, hSession As Long, lReturn As Long

 'get the handle of the current internet connection
 hSession = InternetOpen("vb wininet", 1, vbNullString, vbNullString, 0)
 'get the handle of the url
 If hSession Then hInternet = InternetOpenUrl(hSession, sURL, vbNullString, 0, IF_NO_CACHE_WRITE, 0)
 'if we have the handle, then start reading the web page
 If hInternet Then
 'get the first chunk & buffer it.
 iResult = InternetReadFile(hInternet, sBuffer, BUFFER_LEN, lReturn)
 sData = sBuffer
 'if there's more data then keep reading it into the buffer
 Do While lReturn <> 0
 iResult = InternetReadFile(hInternet, sBuffer, BUFFER_LEN, lReturn)
 sData = sData + Mid(sBuffer, 1, lReturn)
 Loop
 End If

 'close the URL
 iResult = InternetCloseHandle(hInternet)

 GetUrlSource = sData
End Function

y se usa asi en el form

Código:

Text1.Text = GetUrlSource("http://www.google.com")

Saludos,
Skipped.

Edited by: Skipped

Iniciado por Skipped

**Nota: Deben agregar la referencia Microsoft XML v3.0

Por que pones en el titulo "Sin OCX" cuando estas haciendo referencia a un componente ActiveX que para el caso es lo mismo? Yo modificaria el titulo para evitar confusiones.

Salu2...

Ya edité el post y están las dos opciones..
Grax por la observación, tienes toda la razón..

Saludos,
Skipped

Edited by: Skipped

otra cosita.. que seria 'ni nada de eso' en el 2do caso...???? porque estás usando una función API de una .dll..... eso también estaría encapsulado en algo 'externo' a tu programa. En todo caso, para que sea totalmente 'a mano' tendrías que armar la clase del objeto que abra la pagina y analice el código fuente, vos mismo.
Por favor, corregime si me equivoco.
Pablo Gener.

Iniciado por pablogener

otra cosita.. que seria 'ni nada de eso' en el 2do caso...???? porque estás usando una función API de una .dll..... eso también estaría encapsulado en algo 'externo' a tu programa. En todo caso, para que sea totalmente 'a mano' tendrías que armar la clase del objeto que abra la pagina y analice el código fuente, vos mismo.

A ver si entendemos el asunto. No es lo mismo tirar de una API comun en Windows como es la wininet.dll, que viene preinstalada en todas las versiones de Windows, que de un OCX que no viene preinstalado en el sistema por defecto. Lo primero es portable, lo segundo requiere instalar un paquete completo de librerias. Ademas, me gustaria ve a alguien acceder al codigo fuente de una pagina web online desde Visual Basic 6.0 sin usar una API o un OCX, mas que nada por que el propio lenguaje no ofrece funciones para interactuar con redes.

Salu2...

Si bien lo que dice Ex3 es verdad, vbno tiene clases para acceder a internet desde un proyecto Exe estándar,SI se puese acceder desde un proyecto control activex. ( Para este caso para descarga de archivos )

se podria usar un UC como privado, dentro de un proyecto exe, y te evitarias compilar el control y hacer la referencia. (Los controles oxc, tienen algunos métodos, propiedades y eventos para esto.)

...Es una forma mas

Para aclarar:
La idea del segundo codigo es que al usuario del programa no le aparesca:

"el archivo archivo.ocx no esta registrado o fue registrado de forma incorrecta" (algo parecido no se como es huajaja)

y no se tenga que bajar el ocx para usar tu programa.

El wininet.dll en cambio viene en casi todos los PC por defecto, por lo que a casi nadie le saldria un mensaje parecido.

La idea es facilitar el uso del programa sin archivos extras que son algunos ocx que no estan en todos los PC.

repito, tienen toda la razon pero, ¿ que titulos proponen ?
no puedo poner la descripcion anterior en el titulo.

Saludos,
Skipped

Edited by: Skipped

Hola a todos, Skipped muchas gracias por los codigos.
Yo llegue aqui via el gran sabio Google!, ya que estaba buscando un codigo para bajar paginas web,ya tenia el segundo que pusiste y cambie mi codigo por el primero, funciono perfecto, pero sigo con el mismo error aleatorio que tenia antes, lo cual motivo mi busqueda en un principio.
Para empezar, no califico siquiera para principiante ya que yo "programo" en vba, seria mas correcto decir que hago macros a que programo en vb.
El problema es que tengo una macro en excel xp que baja paginas dinamicas hechas con php y sql y las procesa, el problema es que aleatoreamente en lugar de bajar la pagina de Internet, la saca de algun cache supongo, ya que en las paginas esta la fecha y caprichosamente hay paginas que se niega a bajar, mostrandome una vieja.
Cuando pasa esto, no me queda otra mas que cerrar la planilla y abrirla nuevamente, con lo cual, todo regresa a la normalidad.
No tengo idea cual es el problema, pero estoy un 99.9% seguro que es por mi falta de conocimientos, (dejo un0.1% de posibilidades que no sea error mio por si la casualidad jugo a mi favor )
Resumiendo, ¿como hago para que no lea del cache y siempre baje la pagina de Internet?
Desde ya, muchas gracias por leer mi pregunta.
Saludos cordiales.

muchas gracias

Gracias!!!