Buenas:


alguien sabe como puedo hacer que mi programa cambie mi resolucion a 1280 x 1024 y que cuando lo cierre me lo deje como estaba.


merci

En la pagina del guille encontre algo que te puede servir nada mas tienes que adaptarlo, el Link es http://www.elguille.info/VB/utilidades/cambiar_res.htm

Crea Nombre
Command&nbsp ; Command1
Un Arreglo de labels Label1
Un ChexkBox&nbs p;chkBits
un ListBox&nbsp ;List1


y Pega este codigo en el formulario:

Código:

Option Explicit


Private Type tResol
 Width As Long
 Height As Long
 Bits As Integer
End Type
Private Disponibles() As tResol


Private Declare Function EnumDisplaySettings Lib "user32" Alias "EnumDisplaySettingsA" _
 (ByVal lpszDeviceName As Long, ByVal iModeNum As Long, _
 lpDevMode As Any) As Boolean


Private Declare Function ChangeDisplaySettings Lib "user32" Alias "ChangeDisplaySettingsA" _
 (lpDevMode As Any, ByVal dwflags As Long) As Long


Const CCDEVICENAME = 32
Const CCFORMNAME = 32
'Las declaraciones de estas constantes están en: Wingdi.h
Const DM_BITSPERPEL = &H40000
Const DM_PELSWIDTH = &H80000
Const DM_PELSHEIGHT = &H100000


Private Type DEVMODE
 dmDeviceName As String * CCDEVICENAME
 dmSpecVersion As Integer
 dmDriverVersion As Integer
 dmSize As Integer
 dmDriverExtra As Integer


 dmFields As Long
 dmOrientation As Integer
 dmPaperSize As Integer
 dmPaperLength As Integer
 dmPaperWidth As Integer
 dmScale As Integer
 dmCopies As Integer
 dmDefaultSource As Integer
 dmPrintQuality As Integer
 dmColor As Integer
 dmDuplex As Integer
 dmYResolution As Integer
 dmTTOption As Integer
 dmCollate As Integer


 dmFormName As String * CCFORMNAME
 dmUnusedPadding As Integer
 dmBitsPerPel As Integer
 dmPelsWidth As Long
 dmPelsHeight As Long
 dmDisplayFlags As Long
 dmDisplayFrequency As Long
End Type
Dim DevM As DEVMODE


Private Sub Form_Load()
 'Mostrar las resoluciones disponibles
 Dim a As Boolean
 Dim i As Long


 With Screen
 Label1(0) = "Resolución actual: " & (.Width \ .TwipsPerPixelX) & " x " & _
    (.Height \ .TwipsPerPixelY)
 End With
 i = 0
 Do
 a = EnumDisplaySettings(0&, i&, DevM)
 i = i + 1
 If a Then
   'Mostrar en el listbox las resoluciones disponibles
   List1.AddItem Format$(DevM.dmPelsWidth, " @@@@") & " x " & _
   Format$(DevM.dmPelsHeight, "@@@@") & " " & _
   Format$(DevM.dmBitsPerPel, "@@") & " bits"
   'Guardar esos datos en nuestro array
   'de las resoluciones disponibles
   ReDim Preserve Disponibles(i - 1)
   With Disponibles(i - 1)
   .Width = DevM.dmPelsWidth
   .Height = DevM.dmPelsHeight
   .Bits = DevM.dmBitsPerPel
   End With
 End If
 Loop While a
 'Deshabilitar el botón hasta que se seleccione algo
 Command1.Enabled = False
End Sub


Private Sub Command1_Click()
 'Cambiar a la resolución indicada
 Dim i As Long


 'índice de la selección en el ListBox
 i = List1.ListIndex


 'Se le indica los campos a tener en cuenta
 '
 'Si sólo se quiere cambiar la resolución,
 'manteniendo los colores:
 DevM.dmFields = DM_PELSWIDTH Or DM_PELSHEIGHT
 'Si se quiere cambiar también los colores
 If chkBits.Value Then
 DevM.dmFields = DevM.dmFields Or DM_BITSPERPEL
 'DevM.dmFields = DM_PELSWIDTH Or DM_PELSHEIGHT Or DM_BITSPERPEL
 End If


 With Disponibles(i)
 DevM.dmPelsWidth = .Width
 DevM.dmPelsHeight = .Height
 DevM.dmBitsPerPel = .Bits
 End With


 Call ChangeDisplaySettings(DevM, 0)


 With Screen
 Label1(0) = "Resolución actual: " & (.Width \ .TwipsPerPixelX) & " x " & _
    (.Height \ .TwipsPerPixelY)
 End With


End Sub


Private Sub List1_Click()
 Dim i As Long


 i = List1.ListIndex
 'Mostrar en el label la resolución seleccionada
 Label1(1) = "Cambiar a: " & Disponibles(i).Width & " x " & _
   Disponibles(i).Height & " " & _
   Disponibles(i).Bits & " bits"
 'Ya hay una selección, habilitamos el botón
 Command1.Enabled = True
End Sub

Suerte

No recomiendo hacer cambios de resolucion mediante el GDI de Windows por que este efectua cambios permanentes en el sistema de video de Windows y por ello genera problemas en la organizacion de iconos del escritorio cuando asi como otros problemas mas graves. Para esto podrias hacerlo a traves de algun API de bajo nivel como DirectX. Por ejemplo, este codigo te aplica a pantalla completa a la resolucion que le indiques (y que tu dispositivo grafico te soporte, claro) la ventana de tu programa mediante el API grafico 2D de DirectDraw, y en cuanto tu programa deje de correr o pierda el foco automaticamente se restaura la resolucion del escritorio, sin afectar en absoluto a nada mas. Es mas seguro que hacerlo con el GDI.

Código:

Option Explicit<br style="color: rgb(0, 0, 255);"><br style="color: rgb(0, 0, 255);">Dim dx As New DirectX7 'Objeto que hace referencia a DirectX.
Dim dd As DirectDraw7 'Objeto que hace referencia a DirectDraw.

Private Sub Form_Load()
 Set dd = dx.DirectDrawCreate("")
 Call dd.SetCooperativeLevel(Me.hWnd, DDSCL_FULLSCREEN Or DDSCL_ALLOWMODEX Or DDSCL_EXCLUSIVE)
 
 'En esta linea definimos la resolucion a la que queremos se muestre la ventana: 640x480x 800x600, etc...<br style="color: rgb(0, 153, 0);"> 'Debe ser una resolucion estandar aceptada por la tarjeta de video. En este caso ponemos el formulario<br style="color: rgb(0, 153, 0);"> 'a una resolucion de 640 pixeles de ancho por 480 pixeles de alto a 16 bits de color:<br style="color: rgb(0, 153, 0);"> Call dd.SetDisplayMode(640, 480, 16, 0, DDSDM_DEFAULT)
 
End Sub

Si ejecutas y haces un Alt+Tabulador para cambiar de programa veras que en cuanto tu programa pierda el foco se resestablece el modo de video que tenias antes. En verdad es una falsa sensacion ya que nunca se ha variado el modo de video del GDI si no que se ha habilitado un modo exclusivo para tu programa y que accede directamente a la memoria, por ello no se ve afectado el escritorio ni ningun otro programa.

Otro consejo, una resolucion como 1280 x 1024 no es soportada por todas las tarjetas de video o todos lo monitores (el mio por ejemplo). Lo recomendable es una resolucion a 1024x768 como maximo asegurandote de esta forma que cualquiera pueda utilizar tu programa sin miedo a que le destroces la estabilidad del monitor dejandole inaccesible el ordenador (cuando aplicas una resolucion mayor a la que soporta tu monitor te quedas a ciegas). En este caso, DirectX te salva el pellejo, ya que si no es soportada la resolucion por el monitor, en cuanto cierres el programa o este pierda el foco volverias al modo que tiene establecido Windows.

Ahi queda mi consejo.

Salu2...

buenas:


tengo un problema con el codigo de [EX3]:


dx As New DirectX7


me dice que el codigo anteriornose hadefinidio el tipo definido del usuario.


como se puede arreglar??


merci

Perdon, se me olvido con las prisas. Abre la ventana de referencias y añade la referencia a DirectX 7. Buscala por:

DirectX 7 for Visual Basic Type Library

Salu2...