Buenas tengo dos funciones para saver si estoy conectado a internet, si bien en mi caso ambas funcionan bien me gustaria me dieran su opinion cual es mas combeniente y porque, yo la voy a utilizar para que si no se esta conectado a internet , pues que se conecte
pregunto esto mas que nada porque recuerdo que una ves Luciano comento que una forma no podria llegar a ser efectiva dependiendo no recuerdo que caso (que mala memoria) , creo que el problema se podria dar en una red Lan donde una de las dos funciones podria fallar devido que que detecta una conexion a internet y en realidad no la hay.

Primera Funcion

Código:

Private Declare Function InternetGetConnectedState Lib "wininet.dll" (ByRef lpdwFlags As Long, ByVal dwReserved As Long) As Long

Public Function IsOnline() As Boolean
 IsOnline = InternetGetConnectedState(0&, 0&)
End Function

Segunda Funcion

Código:

Declare Function RasEnumConnections Lib "RasApi32.DLL" Alias "RasEnumConnectionsA" (lprasconn As Any, lpcb As Long, lpcConnections As Long) As Long

Function RASCount() As Integer
 Dim lprasconn(0 To 1) As Long ' dummy buffer area
 Dim rc As Long ' return code
 Dim lpcb As Long ' buffer size
 Dim lpcConnections As Long ' connection count

 lprasconn(0) = 32 ' each returned item is at least 32 bytes long
 lpcb = 0 ' set total number of usable bytes in the buffer to zero
 
 rc = RasEnumConnections(lprasconn(0), lpcb, lpcConnections)
 RASCount = lpcConnections ' return connection count

End Function

Si mal no interpreto la primera hace referencia a internet y la segunda al moden

Saludos

Edited by: Leandro

Yo creo que la primera es mas conveniente ya que:

1- Mas corta

2- Usa el "wininet.dll" que viene por defectos en casi todos los equipos, en cambio la otra usa "RasApi32.dll" que es mucho menos conocida que la primera y no creo que la tengan tantos equipos como la primera.

2- La primera es mas general, ya que como dijiste, hace referencia al internet, en cambio la segunda hace referencia al modem, pero, ¿ que pasaría si la conexión es por cable ?

s4lud0s,
Skipped

PD: las podrias poner en la guia de recursos.

Edited by: Skipped

Tengo la ligera sospecha de que wininet.dll internamente utiliza funciones de RasApi32.dll, quizas digo cualquiera , pero e visto que RasApi32 trae muchas mas funciones y con mas opciones para conectar a internet , ambas debuelven un numero de error si no se conecta , y solo RasApi32 debuelve el string del error , ademas esta te da la opcion de poder ingresas un usuario y contraseña para conectar, cosa que wininet despliega automaticamente el usuario y contraseña por defecto.
por lo si es mas corta no importa mucho, lo que si es interesante la pregunta , y si la conexion es por cable ?, que no tengo ni idea de como es.

Saludos

Holga

Si, yo tengo menos memoria que vos jeje, y no me acuerdo pero una ves una de esos ejemplos no me funcionaba y fallaba.

Yo lo habia probado en dos máquinas en red , que tenian conexión compartida a internet. (Lastima que ahora no lo pueda confirmar por que no tengo las pc para probar)

Igual Leandro ..te paso un ejemplo, que es parecido al que usa RasEnumConnections , con una Api mas ( RasGetConnectStatus )

...no me preguntes como funciona, por que no tengo idea ..saludos

Código:

Option Explicit
Public Declare Function RasEnumConnections Lib "RasApi32.dll" _
 Alias "RasEnumConnectionsA" ( _
 lpRasCon As Any, _
 lpcb As Long, _
 lpcConnections As Long) As Long
Public Declare Function RasGetConnectStatus Lib "RasApi32.dll" _
 Alias "RasGetConnectStatusA" ( _
 ByVal hRasCon As Long, _
 lpStatus As Any) As Long
Public Const RAS95_MaxEntryName = 256
Public Const RAS95_MaxDeviceType = 16
Public Const RAS95_MaxDeviceName = 32
Public Type RASCONN95
 dwSize As Long
 hRasCon As Long
 szEntryName(RAS95_MaxEntryName) As Byte
 szDeviceType(RAS95_MaxDeviceType) As Byte
 szDeviceName(RAS95_MaxDeviceName) As Byte
End Type
Public Type RASCONNSTATUS95
 dwSize As Long
 RasConnState As Long
 dwError As Long
 szDeviceType(RAS95_MaxDeviceType) As Byte
 szDeviceName(RAS95_MaxDeviceName) As Byte
End Type
 

Public Function IsConnected() As Boolean
Dim TRasCon(255) As RASCONN95
Dim lg As Long
Dim lpcon As Long
Dim RetVal As Long
Dim Tstatus As RASCONNSTATUS95
 TRasCon(0).dwSize = 412
 lg = 256 * TRasCon(0).dwSize
 RetVal = RasEnumConnections(TRasCon(0), lg, lpcon)
 If RetVal <> 0 Then
 MsgBox "Hubo un error"
 Exit Function
 End If
 Tstatus.dwSize = 160
 RetVal = RasGetConnectStatus(TRasCon(0).hRasCon, Tstatus)
 
 If Tstatus.RasConnState = &H2000 Then
 IsConnected = True
 Else
 IsConnected = False
 End If
End Function

en un form:

Código:

Private Sub Form_Load()
 
 If IsConnected Then
 MsgBox ("si")
 Else
 MsgBox ("No")
 End If
End Sub

Yo solo tengo un comentario basado en lo que pude leer (no investigar) sobre el primer post.

1. La primera funcion verifica si hay conexión a internet, es decir, se presume que para esto ya hubo una marcación previa al proveedor (sea por modem, cable o por xDSL).

2. La segunda opción hace referencia a la API de marcación, pero eso no quiere decir que si se encuentra conectado sea directamente a internet, sino que puede haber conexión directa entre 2 pc's, por lo que en este caso daría como verdadero si encuentra que se a realizado una conexión aunque no sea exactamente internet.

Por tanto:

Al menos para mi, para verificar si estoy conectado a internet, ocuparia la primera funcion, simplemente por ser mas directa y efectiva, y sobre todo mas corta

Saludos