Hola como van,

alguien sabe como consultar servidores (SQL especificamente), que se encuentren activos para ser accesados?

por ejemplo cuando uno crea manualmente un ODBC y muestra una lista de servidores para conectarse.

Si no me explique bien, porfavor diganlo e intentare ser mas claro; gracias por la atencion prestada.

CONSULTAR SERVIDORES MS_SQL ACTIVOS ...

Una forma de obtener Servidores MS_SQL activos en nuestra red, es enviar un byte conteniendo 0x02, via un control Winsock, al puerto 1434 (el puerto que, por default, queda configurado como puerto de escucha en los servidores MS_SQL) usando 255.255.255.255 como IP destino y UDP como protocolo(hacer un "broadcast" o transmisión de datos para ver quién responde al mismo), y pegando el oido en el Winsock (.Bind) a un puerto determinado para recibir allí la información esperada.

Los servidores MS_SQL (V7, 2000, 2005) que reciban dicho byte 0x02 en el mencionado puerto 1434, responderán con una cadena de bytes conteniendo, entre otros datos, el nombre del servidor, el nombre de la instancia y la versión del servidor. Con estos datos deberia sernos suficiente para poder establecer la comunicación con los mismos.

Dicha cadena de bytes es de longitud variable, dado que variables son laslongitudes de los datos que envían.

Esta cadena puede traer3 bytes al inicio de la misma que no nos interesan, más los datos en pares "nombre dato;valor dato;" más un";" adicional al final de la cadena enviada por el servidor, como marcador de fin de datos.

Un ejemplo de cadena enviada por un servidor SQL2000 es esta:

ServerName;SEMPERFI-HOME;InstanceName;MSSQLSERVER;IsClustered;No;Versi on;8.00.194;tcp;1433;np;\\SEMPERFI-HOME\pipe\sql\query;;

Al recibir los datos en nuestro control Winsock (evento _DataArrival), recibiremos en un solo bloque dos o más cadenas de datos provenientes de diferentes servidores. Por supuesto, si sólo existe un servidor en nuestra red, sólo una cadena recibiremos.

Se debe considerar que, en caso de dos o mas servidores presentes en la red, no hay garantía de que, de las cadenas que recibamos en un evento _DataArrival, la última esté completa. Por ello, será convenientecuidar que nuestra rutina de recepción de estos datos verifique que las cadenas a procesar estén completas, y si no, guardar la cadena incompleta y adicionarle el siguiente bloque que recibamos via el evento _DataArrival.

Otro detalle es que, dependiendo del tráfico en nuestra red, la información enviada por los servidores puede tardar en llegarnos, por lo que deberíamos proporcionarle a nuestro proceso un tiempo razonable para que reciba los bloques de información y no dar por sentado que lo que llego en el primer _DataArrival es todo lo que nos va a llegar.


Bueno, despues de todo el rollo anterior, aqui les dejo ejemplo probado de la teoría expuesta ....

Algun comentario ?

Saludos ...

Código:

Option Explicit
' Componentes requeridos:
'
' ListView1 (control ListView,
' Microsoft Windows Common Controls 6.0
' \Windows\system32\mscomctl.ocx)
' Winsock1 (control Winsock,
' Microsoft Winsock Control
' \Windows\system32\mswinsck.ocx)
'
' Command1 (CommandButton)
' Timer1 (Timer)
'
Dim bDataArrival As Boolean
Dim sData As String
Private Sub Command1_Click()
 Dim byteSend(0 To 0) As Byte
 
 Me.Command1.Enabled = False
 Screen.MousePointer = vbHourglass
 
 Me.ListView1.ListItems.Clear
 
 Me.Winsock1.Close
 
 byteSend(0) = "&h02"
 
 Me.Winsock1.Protocol = sckUDPProtocol
 Me.Winsock1.Bind 14340 ' pegamos el oido a este puerto para recibir datos
 Me.Winsock1.RemoteHost = "255.255.255.255" ' Broadcast a toda la red
 Me.Winsock1.RemotePort = 1434 ' puerto default que escuchan los MSSQLServers
 Me.Winsock1.SendData byteSend
 
 Me.Timer1.Interval = 5000 ' 5 segundos de espera entre eventos
 Me.Timer1.Enabled = True
 
 bDataArrival = False
 sData = ""
End Sub
Private Sub Form_Load()
 Me.ListView1.View = lvwReport
 Me.ListView1.LabelEdit = lvwManual
 Me.ListView1.ListItems.Clear
 Me.ListView1.ColumnHeaders.Add , "Server", "Server\Instancia"
 Me.ListView1.ColumnHeaders.Add , "Version", "Version"
 Me.ListView1.ColumnHeaders.Add , "Tipo SQL", "Tipo SQL"
 
 Me.ListView1.ColumnHeaders(1).Width = Me.ListView1.Width / 3
 Me.ListView1.ColumnHeaders(2).Width = Me.ListView1.Width / 3
 Me.ListView1.ColumnHeaders(3).Width = Me.ListView1.Width / 3
 
 Me.Timer1.Enabled = False
 Me.Winsock1.Close
 Me.Command1.Caption = "Carga SQL Servers"
End Sub
Private Sub Timer1_Timer()
 ' Si en los últimos 5 segundos se recibieron datos, apago la bandera
 ' a ver si se enciende durante los próximos 5 segundos ...
 If bDataArrival Then
 bDataArrival = False
 Else
 ' En los últimos 5 segundos no se recibió mas información, por lo que
 ' procedemos a cerrar el Winsock, desactivar el timer y dar por
 ' terminado el ciclo de espera
 Me.Winsock1.Close
 Me.Timer1.Enabled = False
 Screen.MousePointer = vbArrow
 Me.Command1.Enabled = True
 End If
End Sub
Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
 Dim sBinary() As Byte
 Dim sString As String, nCol As Long, nColFin As Long
 Dim sServer As String, sInstance As String
 Dim sVersion As String, sTipoServer As String
 Dim oListItem As ListItem
 
 bDataArrival = True 'Encendemos la bandera para darnos otros 5 segundos
 
 Me.Winsock1.GetData sBinary, vbArray + vbByte, bytesTotal
 
 sString = ""
 For nCol = LBound(sBinary) To UBound(sBinary)
 sString = sString & Chr(sBinary(nCol))
 Next
 
 Debug.Print
 Debug.Print sString ' Observa lo que se recibe en el ImmediateWindow !
 
 sData = sData & sString
 
 ' Iniciamos procesamiento de sData ...
 
 Do While True
 sString = ""
 
 ' Verificar si tenemos una cadena completa para procesarla
 ' La cadena a procesar deberá contener "ServerName;" y adelante
 ' de esto, un doble ";".. Si cumple el requisito, procesaremos
 ' esta subcadena.. Si no, dejamos esta cadena como está y salimos
 ' del SUB para esperar un nuevo _DataArrival ...
 
 nCol = InStr(1, UCase(sData), "SERVERNAME;", vbTextCompare)
 If nCol > 0 Then
 nColFin = InStr(nCol + 11, sData, ";;", vbTextCompare)
 If nColFin > nCol Then
 ' Tenemos una cadena completa !
 ' La extraemos para procesarla
 sString = Mid(sData, nCol, (nColFin - nCol) + 2)
 ' Dejamos en sData los datos siguientes al ";;" para
 ' el siguiente loop ...
 sData = Mid(sData, nColFin + 2)
 Else
 ' la cadena no esta completa ...
 ' Salimos del SUB dejando sData tal y como está
 Exit Sub
 End If
 Else
 ' cadena incompleta o vacia... salir del SUB
 Exit Sub
 End If
 
 sServer = "": sInstance = "": sVersion = "": sTipoServer = ""
 
 ' Extraer el ServerName ...
 nCol = InStr(1, UCase(sString), "SERVERNAME;", vbTextCompare)
 If nCol > 0 Then
 nCol = nCol + 11 'primer caracter del nombre del servidor
 nColFin = InStr(nCol, sString, ";", vbTextCompare)
 If nColFin > nCol Then
 sServer = Mid(sString, nCol, (nColFin - nCol))
 End If
 End If
 
 ' Extraer la instancia del servidor
 nCol = InStr(1, UCase(sString), "INSTANCENAME;", vbTextCompare)
 If nCol > 0 Then
 nCol = nCol + 13 'primer caracter del nombre de la instancia
 nColFin = InStr(nCol, sString, ";", vbTextCompare)
 If nColFin > nCol Then
 sInstance = Mid(sString, nCol, (nColFin - nCol))
 End If
 End If

 ' Extraer la version del servidor
 nCol = InStr(1, UCase(sString), "VERSION;", vbTextCompare)
 If nCol > 0 Then
 nCol = nCol + 8 'primer caracter de la version del servidor
 nColFin = InStr(nCol, sString, ";", vbTextCompare)
 If nColFin > nCol Then
 sVersion = Mid(sString, nCol, (nColFin - nCol))
 End If
 End If
 
 ' Con base en la versión, determinamos la versión tipo de SQLServer
 ' Verificamos sólo la parte entera de la version ...
 If Trim(sVersion) <> "" Then
 nCol = InStr(1, sVersion, ".")
 If nCol > 0 Then
 sTipoServer = Mid(sVersion, 1, nCol - 1)
 Else
 sTipoServer = sVersion
 End If
 
 If CInt(sTipoServer) = 7 Then
 sTipoServer = "MS SQL V7"
 ElseIf CInt(sTipoServer) = 8 Then
 sTipoServer = "MS SQL 2000"
 ElseIf CInt(sTipoServer) = 9 Then
 sTipoServer = "MS SQL 2005"
 Else
 sTipoServer = "MS SQL ???"
 End If
 End If
 
 ' En SQL2000, el nombre de la instancia DEFAULT es MSSQLSERVER ...
 ' Si esto es lo que tenemos, podemos ignorarla en el armado del
 ' nombre completo del server ...
 
 If Not UCase(sInstance) = "MSSQLSERVER" Then
 sServer = sServer & "\" & sInstance
 End If
 
 ' Agregamos el servidor a nuestra lista de servidores ...
 Set oListItem = Me.ListView1.ListItems.Add(, sServer, sServer)
 oListItem.SubItems(1) = sVersion
 oListItem.SubItems(2) = sTipoServer
 
 Set oListItem = Nothing
 
 Loop
 
End Sub

Hola,parece interesante el codigo de Semper,pero lo he probado y no me funciona,es decir parece que busca al apretar el boton ,pero no devuelve nada...tengo un servidor local en mi pc SQL 2005...pero lo que yo entendi del primer post es que queres saber la lista de los DNS que esta en la ventana de Crear ODBC, o sea esto???

Listar Dsn de sistema y de usuario

saludos.

Hola,

gracias por las respuestas, pero tal vez si pregunte mal; en realidad no son servidores "activos" como tal, sino, los servidores disponibles, sean locales o en red que tengamos en la maquina. Muy interesantes ambas respuestas, no las he probado por estar trabajando, pero se ven muy bien.

Por DSN no hay problemas, ya que yo creo el ODBC por codigo y no hay problema, lo que necesito es saber a que servidor lo voy a dirigir, sin intervencion del usuario.

PD: Intentare postear una imagen con lo que les quiero decir.

http://www.voguehost.com/ims/u/Rawl/...ervidorSQL.JPG

seba123neo... el codigo que postee es precisamente lo que Rawl necesita ...

Sobre que no te funciono el codigo, mencionas que tienes SQL2005 instalado en tu equipo ...

Yo tengo SQL2000 y 2005 Express instalados en mi equipo y funciona sin problemas... Lo he probado en otros equipos con solamente SQL2000 y/o solamente SQL2005 instalado, y no ha surgido problema alguno...

En los servicios de tu equipo, tienes iniciado el SQLServerBrowser ?
El puerto de escucha de tu SQLServer es el 1434 ? (aunque creo que esto ultimo no es modificable por el usuario)...

Me parece que tambien habria que verificar si tu SQL Server no tiene habilitada la opcion de "esconder" el server (HIDE Server o algo asi), pues si esta habilitada esta opcion, al server solo se tendra acceso conociendo de antemano el nombre\instancia del mismo...

Otra cosa segun los documentos que he leido, puede ser que no se tenga habilitado el protocolo TCP en el SQLServer o que el firewall en uso este bloqueando el proceso... cosa rara pero puede suceder, segun los documentos ...

Si en tu ODBC,al crear un DSN para SQL Server, te muestra el servidor que tienes instalado (tal como las imagenes que Rawl posteo), entonces el codigo quepuse deberia haber funcionado ....

Bueno, veamos que resulta ...

Saludos !

tengo el browser activado y el servidor activado...pero cuando voy a crear un DNS para SQL Server me sale esa ventana,pero no me sale ningun servidor dispobile en la lista del combobox...

saludos.

tengo el mismo problema de seba123neo, intenta cargar algo, pero no trae nada, deberia traerme el servidor local. Instale el SQL 2005 Express

Al crear un DSN en los ODBC, te lista los servers disponibles? En tu caso, el SQL2005 que instalaste ?

Si al igual que a seba, no te aparece listado tu server, entonces tienes un problema de configuracion de puertos ... No se tiene acceso al puerto 1434 via UDP en tu equipo ...

Si tienes activado el Firewall de Windows, abre su configuracion, y en la pestaña de Excepciones, agrega el puerto 1434, UDP a la lista autorizada ...
Si es otro Firewall el que usas, configura dicho puerto segun proceda...

Probe en mis equipos activando el Firewall de Windows y, por default, no me lista los servers... Al aplicar el cambio descrito, ya funciona el listado de servidores nuevamente...

Saludos ...

ahora anda Semper!!!!! era el puerto nomas....ya funciona todo bien...

que raro que no lo hace automatico a esto de abrir el puerto...o te da para elegir si queres abrirlo o no...como sucede con todos los programas que manejan puertos...

saludos.

Perfecto seba!!! Si, es raro que dicho puerto no lo autoconfigure la misma instalaciondel SQL2005, si el mismo esta reservado exclusivamente para MSSQLServer con este fin precisamente: dar ping a los servidores en la red...

Bueno, a ver ahora con Rawl ...

Saludos !!

haha hice todo al revez, en el trabajo saco los odbc y el programa lo probe en casa.

En casa no me saca ni para configurar el ODBC a un sql server "SQL Native", imagino que debo instalar alguna libreria de algun modo. Pero porbare en el trabajo y te confirmare, pero revise el codigo y de veras que esta bien montado, gracias por responderme y felicitaciones, por un codigo tan util y bien hecho.

Gracias a ambos