Hola a todos,este funcion me va bien pero como tengo que estar desarrollando otro proyecto tengo que volver a rehacerlo a razon que cambian los que se desea ver en los controles de texto, aveces son siete en otras veces son 11 , pretendo tenerlo en un modulo de clase y solo llamarlo.

Codigo
-------------------------------------------------
Function VerificaR(xSW As Boolean)
If txtNombre = "" Then
MsgBox " Falta ingresar el MONBRE ", vbCritical, "Error al ingresar Datos"
txtNombre.SetFocus
xSW = True
Exit Function
End If
If txtApellido = "" Then
MsgBox " Falta ingresar elAPELLIDO ", vbCritical, "Error al ingresar Datos"
txtApellido.SetFocus
xSW = True
Exit Function
End If
If txtDireccion = "" Then
MsgBox " Falta ingresar el DIRECCION ", vbCritical, "Error al ingresar Datos"
txtDireccion.SetFocus
xSW = True
Exit Function
End If
If txtTelefono = "" Then
MsgBox " Falta ingresar el TELEFONO ", vbCritical, "Error al ingresar Datos"
txtTelefono.SetFocus
xSW = True
Exit Function
End If
If txtDNI = "" Then
MsgBox " Falta ingresar el DNI ", vbCritical, "Error al ingresar Datos"
txtDNI.SetFocus
xSW = True
Exit Function
End If
If txtEMail = "" Then
MsgBox " Falta ingresar el EMail ", vbCritical, "Error al ingresar Datos"
txtEMail.SetFocus
xSW = True
Exit Function
End If
End Function
----------------------------------------------------------------------------
Si se fijan los text no son array, intente con controles array el probles es que no puedo usar la cabesera de la base de datos estan escrito por ejemplo asi Nom_cli, Ape_cli, etc, etc.
lo ideal seria usar controles array pero que funcione en modulo de clase como la funcion descrita en el codigo y nose como hacer, gracias de ante mano

Hola,

Te acosejo que recorras los controles con un For Each

Ej:

Código:

Dim Text As Control
For Each Text In Me.Controls
 If TypeOf Text Is TextBox Then
 If Text.Text = "Text1" Then Text.Text = "Hola"
 End If
Next

Si los txt a verificar no son todos lo que yo haría es separar el nombre de todos los text y ponerlo en una variable
Ej: Cadena = "|txtNombre|txtApellido|txtDireccion|etc...|"
(Notá que comienza y termina con "|"
Luego verificás que el nombre esté incuido en la cadena

Código:

If Instr(1, "|" & Text.Name & "|", Cadena) > 0

Luego, para el mensaje podés dejar la palabra característica en la propiedad "Tag" del Textbox.

Saluods

exelente Vanchi, pero ya lo probe no es lo que necesito, sugeriria que prueben el codigo de la fincion es para que el usuario se olvidara de ingresar algun dato el programa verifica cual de las textobox esta vacia atraves de un msgbox le indica que tal casilla o textobox, ahora bien este codigo y/o funcion debe ser reutilizado muchas veces y que los textobox varias puede ser 5 o 7 sin que se modifique la codificacion, agradeceria una manito en esto porfavor, de nuevo gracias Vanchi.

PercyP, vuelve a leer todo el post de Vanchi, pues lo que te propone es exactamente lo que pides (a no ser que te esté entendiendo mal).

fijate que te dice que coloques la palabra característica en la propiedad "Tag" de cada textbox, así que en el bucle for sólo deberías agregar la propiedad tag al mensaje

Código:

MsgBox " Falta ingresar el " & Text.Tag, vbCritical, "Error al ingresar Datos"
Text.SetFocus
exit for

PercyP, creo que Vanchi y Garfield te han dado todo lo que pedías... y más. Si quieres una función reutilizable (o un módulo de clase...) ¡sólo tienes que escribirla según te han dicho!
Por ejemplo:

Private Function VerificarForm(MyForm As Form) As Boolean

VerificarForm = True
Dim Control As Variant
For Each Control In MyForm.Controls
If Control.Tag > "" Then
If Control.Text = "" Then
MsgBox " Falta ingresar el dato:" & Control.Tag, vbCritical, "Error al ingresar Datos"
Control.SetFocus
VerificarForm = False
Exit For
End If
End If
Next

End Function

Para entretenerme he hecho una modificación, que te pueden servir o no, o según los casos: si no usas la propiedad tag para ninguna otra cosa (imprescindible) la función de arriba ya filtra los controles que te interesan y también te permite incluir Combos o ListBoxes o cualquier control que tenga la propiedad text.
Otra posibilidad sería pasarle a la función no el formulario (o la colección de controles) si no un array de los controles que te interesen... o dos arrays, por si no puedes usar tag,yentonces utilizarla etiqueta del textbox para obtener el nombre del campo... etc, etc, etc....
Saludos.

Hola probá si te sirve algo asi o lo podes adaptar

Form
Option Explicit

' \\ -- Form ( dos Text1 - - Text1 (0), Text1 (1)) -- Class1
' ------------------------------------------------------------------------
' ------------------------------------------------------------------------
' \\ -- Declaraciones
' ------------------------------------------------------------------------
Private WithEvents mClass As Class1
Private Sub Form_Load()

' -- setear txt
Text1(0) = ""
Text1(1) = "asd@asd.com"

Text1(0).Tag = "Nombre"
Text1(0).Tag = "Email"

' -- Crear instancia
Set mClass = New Class1
' -- función para validar el array de txt
With mClass
Call .Validar(Text1)
End With
End Sub
Private Sub Form_Unload(Cancel As Integer)
If Not mClass Is Nothing Then Set mClass = Nothing
End Sub
' ----------------------------------------------------------------------
' \\ -- Evento
' ----------------------------------------------------------------------
Private Sub mClass_Message(xTextBox As TextBox)
MsgBox "El textbox " & CStr(xTextBox.Tag) & " No puede estar vacio", vbExclamation
End Sub




Modulo
Option Explicit
' --------------------------------------------------------------------------
' \\ -- Declaraciones
' --------------------------------------------------------------------------
Private mTextBox() As TextBox
' \\ -- Eventos
Event Message(xTextBox As TextBox)
' ----------------------------------------------------------------------------
' \\ -- Función de validación
' ----------------------------------------------------------------------------
Sub Validar(arrTextBox As Object)
On Error GoTo erro_Handler

Dim xTxt As TextBox
For Each xTxt In arrTextBox
If CStr(xTxt) = vbNullString Then
RaiseEvent Message(xTxt)
End If
Next

' -- Errores ---------------------------------
Exit Sub
erro_Handler:

End Sub

Hola y lo primero mil gracias a Vanchi, Garfield, Hal9000 y a Luciano, por tenerme pasiencia, quien escribe es autodidacta en programacion si bien desarrollo mis proyectos son como los que mostre funcionan, son tediosos, si les preguntaria por cada idea que se me ocurre no tendria cuando acabar, pero una a la vez, otra vez mas gracias.