Hola a todos


Alguien sabe la forma de crear una conexion odbc desde VB6 a oracle?. Es decir me tengo que crear el puente ODBC no la conexion desde VB6 a la BD ya queeso lo hago por ADODB, sino el odbc para poder conectar desde Crystal reports. Lo podria hacer manualmente pero me gustaria que ala arrancar la aplicacion me lo creara automaticamente.


Se crear una conexion ODBC para Access pero no para Oracle.





¿Alguna ayuda?





Un saludo

Hola... Aqui te paso este codigo, de esta forma creo una conexion ODBC para Visual FoxPro...

Código:

'Crear ODBC
Private Declare Function SQLConfigDataSource Lib "ODBCCP32.DLL" (ByVal hwndParent As Long, ByVal fRequest As Long, ByVal lpszDriver As String, ByVal lpszAttributes As String) As Long


Private Const ODBC_ADD_SYS_DSN As Long = 4
Private Const ODBC_REMOVE_SYS_DSN As Long = 6
Private Const vbAPINull As Long = 0&


Public Function Crear_ODBC(sDsnName As String, sOrigen As String) As Boolean


Dim dl As Long
Dim sAttributes As String
Dim sDriver As String


If Dir(sOrigen) = "" Then
 Crear_ODBC = False
 Exit Function
End If


sDriver = "Microsoft Visual FoxPro Driver"


sAttributes = "DSN=" & sDsnName & Chr(0)
sAttributes = sAttributes & "UID=" & Chr(0)
sAttributes = sAttributes & "PWD=" & Chr(0)
sAttributes = sAttributes & "SourceDB=" & sOrigen & Chr(0)
sAttributes = sAttributes & "SourceType=DBC" & Chr(0)
sAttributes = sAttributes & "Exclusive=No" & Chr(0)
sAttributes = sAttributes & "BackgroundFetch=Sí" & Chr(0)
sAttributes = sAttributes & "Collate=Machine"


dl = SQLConfigDataSource(vbAPINull, ODBC_ADD_SYS_DSN, sDriver, sAttributes)


If dl Then
 Crear_ODBC = True
Else
 Crear_ODBC = False
End If


End Function



Public Function Eliminar_ODBC(sDsnName As String) As Boolean


Dim dl As Long
Dim sDriver As String


sDriver = "Microsoft Visual FoxPro Driver"


sDsnName = "DSN=" & sDsnName


dl = SQLConfigDataSource(vbAPINull, ODBC_REMOVE_SYS_DSN, sDriver, sDsnName)


If dl = 1 Then
 Eliminar_ODBC = True
Else
 Eliminar_ODBC = False
End If


End Function

La variable sDsnName, es el nombre de la conexion ODBC a crear. Y sOrigen es la ruta de la base de datos. y la variable sAttributes tendrias q crear una conexion manualmente, entrar al editor de registros y ponerle los mismo atributos q tiene la conexion creada manualmente.
La funcion Crear_ODBC devuelve True si es q la conexion se creo satisfactoriamente sino devuelve False. Igual la funcion Eliminar_ODBC devuelve True si es q la conexion se logro eliminar, sino devuelve False.


Bueno espero q te sirva...


Bye...


Isaac...