hola,tengo una duda,estoy haciendo operaciones matematicas con varios textbox y necesito que estos errores no sean posibles de crearse.

suponganse que tengo un textbox vacio(solo acepta numeros y "," )y quiero que si el textbox esta vacio que no se pueda agregar el caracter "," quiero que solo se pueda agregar ese caracter si hay un numero ya escrito,pero que solo se pueda ingresar uno por ejemplo 3,24 y no 3,,,24. y si se pone por ejemplo 3,24 que despues no se pueda agregar otro "," por ejemplo 3,24,5

probe con funciones de texto InStr para detectar el caracter,pero no me sale.

saludos.

Editado:bueno ya pude resolverlo con una funcion y con un poco de codigo,lo dejo por las dudas alguien le sirve,puede hacerse de otras formas tambien.

la funcion es asi:

Public Function Cuantas(ByVal Letra As String, ByVal Cad As String) As Long
Cuantas = Len(Cad) - Len(Replace(Cad, Letra, vbNullString))
End Function

y lo detecta asi:

If Cuantas(",", Text1.Text) = 2 Then
MsgBox "No podes ingresar 2 comas"
Text1.Text = ""
Exit Sub
End If
If Len(Text1.Text) = 1 Then
If Cuantas(",", Text1.Text) = 1 Then
MsgBox "Ingresa un numero antes de la coma"
Text1.Text = ""
End If
End If
Edited by: seba123neo

hola yo havia echo otra validacion, pero veo que ya lo resolviste , de todas formas te lo dejo por si te sirve, este no te advierte , sino que directamente borra los caracteres no validos

Código:

Option Explicit
Private Sub Text1_Change()
Call Limpiar(Text1)
End Sub

Private Sub Text1_KeyPress(KeyAscii As Integer)
KeyAscii = ValidarKey(Text1, KeyAscii)
End Sub

Private Function ValidarKey(TXT As TextBox, KeyAscii As Integer) As Integer
 If KeyAscii > 47 And KeyAscii < 58 Or KeyAscii = 44 Or KeyAscii = 8 Then
 ValidarKey = KeyAscii
 If InStr(TXT, ",") And KeyAscii = 44 Then ValidarKey = 0
 If TXT = "" And KeyAscii = 44 Then ValidarKey = 0
 Else
 ValidarKey = 0
 End If
End Function

Private Sub Limpiar(TXT As TextBox)
 Dim Ret As Integer, i As Integer
 If Left(TXT, 1) = "," Then TXT = Mid(TXT, 2)
 
 If UBound(Split(TXT, ",")) > 1 Then
 Ret = InStr(TXT, ",")
 TXT = Left(TXT, Ret) & Replace(Mid(TXT, Ret), ",", "")
 End If
 For i = 0 To 255
 If i = 44 Then i = 45
 If i = 48 Then i = 58
 TXT = Replace(TXT, Chr(i), "")
 Next
 TXT.SelStart = Len(TXT)
End Sub

fijate que hay dos rutinas con la de ValidarKey() ya funcionaria , pero el tema es que si se usa el portapapeles no, y la sub Limpiar() tambien funcionaria sola

Saludos



Edited by: Leandro

Para evitar comas repetidas yo implementaria algo similar a esto en el evento LostFocus del control:

Código:

Option Explicit

Private Sub Text1_LostFocus()
 Dim i As Long, tmp As String, ch As String, hc As Boolean
 
 ' Recorremos toda la cadena caracter a caracter:
 For i = 1 To Len(Text1.Text)
 ch = Mid$(Text1.Text, i, 1) ' Obtenemos el caracter.
 
 ' Si el caracter es una coma y no se encontro ninguna todavia
 ' o el caracter no es una coma añadimos el caracter a la cadena temporal:
 If (Not ch = ",") Or (ch = "," And Not hc) Then tmp = tmp & ch
 
 ' Si el caracter añadido es la primera coma encontrada activamos el flag
 ' para evitar añadir mas comas existentes en la cadena original:
 If (ch = "," And Not hc) Then hc = True
 Next
 
 Text1.Text = tmp ' Actualizamos la cadena original por la temporal.
End Sub

De esta forma, aunque te introduzcan un valor mediante Ctrl+V o de la forma que sea, en cuanto el control pierda el foco, que eso siempre ocurre cuando pasas a otro control como un CommandButton u otro TextBox, el valor se formatea correctamente.

Salu2...

Y otra forma más, pero esta en el evento KeyPress

Código:

Private Sub Text1_KeyPress(KeyAscii As Integer)
 If Chr(KeyAscii) = "," Then
 If InStr(Text1, ",") > 0 Or Len(Text1) = 0 Then KeyAscii = 0
 End If
End Sub

Aunque no detectaría el copiar-pegar

Saludos

otra forma más,en el eventochange (que sí detecta copiar- pegar)

Private Sub Text1_Change()
Text1 = Replace(Text1, ".", ",") ' optativo
If InStr(Text1, ",") = 1 Then Text1 = "": Beep ' optativo
If Not IsNumeric(Text1) Then Text1 = "": Beep
End Sub

SALU2

Muchisimas gracias a todos por sus respuestas,no esperaba tantas.me sirvieron todas,estan muy buenas las funciones,las voy a guardar por las dudas.en serio gracias a todos,este foro si que es el mejor de visual basic,porque si haces bien la pregunta y la redactas bien,es casi imposible que no tengas una respuesta.

las estuve probando una a una y les digo los resultados que me resultaron:

la de Leandro esta muy buena,me sirve,pero es bastante larga.la de [EX3] todavia no entiendo porque en el evento lostfocus del textbox,porque digamos que yo lo quiero en el change,o sea mientras escribis,no quiero validar el textbox cuando pierda el foco,pero gracias igual,porqeu la puedo aplicar a otras cosas.La que mas me vendria bien es la de Anibal,primero que es muy cortita y segundo que es lo que quiero porque directamente no deja escribir el caracter,sin embargo la de Dessa que tambien esta buena y corta,pero se nota que se escribe el caracter y despues lo borra.y eso del copiar y pegar no se preocupen porqeu no lo quiero para eso y si alguien trata de pegar con el mouse,le saque el menu con una funcion y si se les ocurre apretar el Control + V ,detecto esas teclas y que no pase nada.

saludos.

Edited by: seba123neo

Iniciado por seba123neo

la de [EX3] todavia no entiendo porque en el evento lostfocus del textbox,porque digamos que yo lo quiero en el change,o sea mientras escribis,no quiero validar el textbox cuando pierda el foco

A veces el evento Change molesta mas que ayuda a la hora de corregir errores en tiempo de escritura (segun que casos, claro). Generalmente, las validaciones se hacen siempre una vez que el control pierde el foco, es el funcionamiento que vas a encontrar en la mayoria de los programas que uses.

Salu2...

Iniciado por EX3

A veces el evento Change molesta mas que ayuda a la hora de corregir errores en tiempo de escritura (segun que casos, claro). Generalmente, las validaciones se hacen siempre una vez que el control pierde el foco, es el funcionamiento que vas a encontrar en la mayoria de los programas que uses.

Si, esta bien lo que decis EX3, pero tambien se puede hacer la validacion en el evento Validate del control
en cuestion. Es un poco mas prolijo (no digo que lo de EX3 este mal,
sino que para eso esta el evento Validate, como su nombre lo indica). Asi no te tenes que andar acordando en cada form donde hiciste la validacion, si en el evento GotFocus, Change o LostFocus. Directamente vas en cualquier form a Validate y listo.

Salu2 a to2

Hola Seba123neo, utilize tu codigo para validar las comas que se ingresan:

If Cuantas(",", Text1.Text) = 2 Then
MsgBox "No podes ingresar 2 comas"
Text1.Text = ""
Exit Sub
End If
If Len(Text1.Text) = 1 Then
If Cuantas(",", Text1.Text) = 1 Then
MsgBox "Ingresa un numero antes de la coma"
Text1.Text = ""
End If
End If

le hice una pequeña correción, porque asi como esta se pueden ingresar mas de 2 comas y no va a tirar ninguna advertencia, si ingresa dos comas evalua el if, pero si se ingresan 3 o mas ya no funciona. Habria que cambiar el = por > y el 2 por un 1, quedando asi
If Cuantas(",", Text1.Text) > 1 Then
MsgBox "No podes ingresar mas de 1 coma"

Espero le sirva a alguien mas