Hola, Estoy haciendo una aplicación despertador. Le puse un boton que abre un common dialog, para elegir el archivo de sonido que se va a ejecutar; y otro para probar el sonido.

Estoy usando: sndPlaySound Archivo, 1
para ejecutar el archivo de sonido (que contiene la variable Archivo)

Tengo dos problemas:
1- no me ejecuta archivos mp3
2- no encuentro la forma de detener la ejecución. Aún saliendo del programa, el archivo se sigue ejecutando hata el final.

saludos

Hola Telu

El api sndplaySound solo reproduce archivos tipo Wav o Wma no Mp3.
Para detener un sonido debes tener también el api sndStopSound,

Private Declare
Function sndStopSound Lib "winmm.dll" Alias "sndPlaySoundA"
(ByVal lpszNull As Long, ByVal uFlags As Long) As LongEspero haberte ayudado

Saludicimos

Hola telu,podes usar la api mciExecute para reproducir archivos mp3 ,wav y Midi facilmente y despues para realizar la pausa solo le pasas los parametros que reconoce esa api y listo.te paso un ejemplo de como usarlo,inicia un nuevo proyecto y inserta en el formulario 4 CommandButton(play,stop,pause,abrir),un commondialog para seleccionar el archivo y un label para ver la ruta del archivo que se esta reproduciendo.este es el codigo:

Código:

Option Explicit
Private Declare Function GetShortPathName Lib "kernel32" Alias "GetShortPathNameA" (ByVal lpszLongPath As String, ByVal lpszShortPath As String, ByVal lBuffer As Long) As Long
Private Declare Function mciExecute Lib "winmm.dll" (ByVal lpstrCommand As String) As Long
Dim ret As Long, path As String

Private Sub Command1_Click()
ejecutar ("Play ")
Habilitar "Play"
End Sub

Private Sub Command2_Click()
ejecutar ("Stop ")
Habilitar "Stop"
End Sub

Private Sub Command3_Click()
ejecutar ("Pause ")
Habilitar "Pause"
End Sub

Private Sub Form_Unload(Cancel As Integer)
mciExecute "Close All"
End Sub

Private Sub Command4_Click()
With CommonDialog1
.Filter = "Archivos Wav|*.wav|Archivos Mp3|*.mp3|Archivos MIDI|*.mid"
.ShowOpen
If .FileName = "" Then
Habilitar "Iniciar"
Exit Sub
Else
PathCorto .FileName
Label1 = .FileName
mciExecute "Close All"
Habilitar "Stop"
End If
End With
End Sub


Private Sub PathCorto(archivo As String)
Dim temp As String * 250
path = String(255, 0)
ret = GetShortPathName(archivo, temp, 164)
path = Replace(temp, Chr(0), "")
End Sub

Private Sub ejecutar(comando As String)
If path = "" Then MsgBox "Error", vbCritical: Exit Sub
mciExecute comando & path
End Sub

Private Sub Form_Load()
Command1.Caption = "Play >>"
Command2.Caption = "Stop ||||"
Command3.Caption = "Pause ||"
Command4.Caption = ":::: Abrir archivo de música ::::"
Habilitar "Iniciar"
Label1 = "": Label1.AutoSize = True
End Sub

Private Sub Habilitar(Accion As String)
Select Case Accion

Case "Iniciar"
Command1.Enabled = False
Command2.Enabled = False
Command3.Enabled = False
Case "Play"
Command1.Enabled = False
Command2.Enabled = True
Command3.Enabled = True
Case "Stop"
Command1.Enabled = True
Command2.Enabled = False
Command3.Enabled = False
Case "Pause"
Command1.Enabled = True
Command2.Enabled = True
Command3.Enabled = False

End Select

End Sub

otra forma mas primitiva digamos seria insertar el ocx de windows media player y ponerlo invisible y pasarle los parametros y listo,este podria reproducir todos los formatos que soporta el windows media.

saludos.

hola amigos, muchas gracias, las dos alternativas funcionan perfectamente, aunque, para lo que estoy haciendo, es mejor la de Seba (mciexecute). por lo de los archivos mp3.
gracias, saludos