Tengo declarada una variable string de esta manera:


Dim sCampoINI As String * 255


(la uso asi porque si no me sale error cuando hago GetPrivateProfileString para ver un archivo .INI)


ahora me pasa que cuando veo el contenido que trae, me muestra la palabra correcta y seguido de muchos caracteres con forma de cuadrado (supongo que hasta completar 255).


Lo que yo quisiera es saber como hago para sacarle esos caracteres que tengo de mas.





gracias!!

Hola aqui encontre estas funciones en la pagina del guille espero q te sirvan...

Código:

'--------------------------------------------------
' Profile.bas                           (24/Feb/97)
' Autor:        Guillermo Som Cerezo, 1997
' Fecha inicio: 24/Feb/97 04:05
'
' Módulo genérico para las llamadas al API
' usando  xxxPrivateProfileString
'---------------------------------- ----------------
Option Explicit

#If Win32 Then
    'Declaraciones para 32 bits
    Private Declare Function GetPrivateProfileString Lib "Kernel32" Alias "GetPrivateProfileStringA" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpDefault As String, ByVal lpReturnedString As String, _
         ByVal nSize As Long, ByVal lpFileName As String) As Long
    Private Declare Function WritePrivateProfileString Lib "Kernel32" Alias "WritePrivateProfileStringA" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpString As Any, ByVal lpFileName As String) As Long
#Else
    'Declaraciones para 16 bits
    Private Declare Function GetPrivateProfileString Lib "Kernel" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpDefault As String, ByVal lpReturnedString As String, _
         ByVal nSize As Integer, ByVal lpFileName As String) As Integer
    Private Declare Function WritePrivateProfileString Lib "Kernel" _
        (ByVal lpApplicationName As String, ByVal lpKeyName As Any, _
         ByVal lpString As Any, ByVal lplFileName As String) As Integer
#End If


Public Function LeerIni(lpFileName As String, lpAppName As String, lpKeyName As String, Optional vDefault) As String
    'Los parámetros son:
    'lpFileName:    La Aplicación (fichero INI)
    'lpAppName:     La sección que suele estar entrre corchetes
    'lpKeyName:     Clave
    'vDefault:      Valor opcional que devolverá
    '               si no se encuentra la clave.
    '
    Dim lpString As String
    Dim LTmp As Long
    Dim sRetVal As String

    'Si no se especifica el valor por defecto,
    'asignar incialmente una cadena vacía
    If IsMissing(vDefault) Then
        lpString = ""
    Else
        lpString = vDefault
    End If

    sRetVal = String$(255, 0)

    LTmp = GetPrivateProfileString(lpAppName, lpKeyName, lpString, sRetVal, Len(sRetVal), lpFileName)
    If LTmp = 0 Then
        LeerIni = lpString
    Else
        LeerIni = Left(sRetVal, LTmp)
    End If
End Function


Sub GuardarIni(lpFileName As String, lpAppName As String, lpKeyName As String, lpString As String)
    'Guarda los datos de configuración
    'Los parámetros son los mismos que en LeerIni
    'Siendo lpString el valor a guardar
    '
    Dim LTmp As Long

    LTmp = WritePrivateProfileString(lpAppName, lpKeyName, lpString, lpFileName)
End Sub

Por lo q veo LTmp = GetPrivateProfileString(.....), devuelve un entero con el numero de caracteres q tiene la variable en el cual se devuelve el valor de la clave, por ese usa Left(sRetVal, LTmp) para obtener la clave.


O tambien puedes trabajar con registros de windows, creo q en la guia de recursos hay ejemplo o puedes trabajar con SaveSetting, GetSetting y GetAllSettings funciones propias de VB.


Bueno Bye...Edited by: Isaac

Si no de tods modos en la guia de recursos esta dos formas de leer y escribir inis hay puedes checar por que el post que puse,nunca me ha fallado de esa manera

Contestando a la pregunta original;eliminar los caracteres nulos de la cadena:

Código:

 If (InStr(sCampoINI, Chr(0)) > 0) Then
 sCampoINI = Left(sCampoINI, InStr(sCampoINI, Chr(0)) - 1)
 End If

Esta instrucción la puedes poner en una función que devolverá el texto sin los caracteres nulos.


Saludos