Buenas. Quiero implementa a mi proyecto la autonomia de poderse cerrar remotamente y poder arrancarla remotamente. Todo esto lo consigo perfectamente. Mi problema es que mi aplicacion depende del factor humano ya que a la web donde se conecta mi aplicacion se debe entrar con usuario y contraseña. Mirando en el foro (antes de preguntar) todo lo que he encontrado se refiere al logeo en una web mediante el control de los textbox donde hay que introducir user y password, mediante el nombre del control del web. Esto lo domino bastante bien gracias a la ayuda que recibí en su dia de Seba123Neo y al programa TamperIE que sumado al Mozilla, el cual edita el codigo fuente de una web, me da la posibilidad de controlar textbox, listbox, commandbutton, etc....sin problemas.

El gran problema que tengo es que la pagina web a donde me tengo que conectar y logearme no tiene un par de textbox donde introducir mi usuario y password, sino que presenta un formulario modal con los 2 textbox y 2 botones para Aceptar y cancelar. No hay nada en el codigo fuente de la pagina en donde esta el hipervinculo que hace saltar el form modal para acceder.

La pagina es https://eagora.telefonica.es/portal/...agora-publico/ y el formulario modal sale al hacer click en el enlace llamado "Usuarios Registrados". Entonces aparece el Form en estado modal y ahi hay que poner el usuario y la contraseña para acceder. No se como automatizar esto ya que no tengo datos de este Form Modal. No puedo ver su codigo fuente, por lo que no se por donde empezar.

Si consigo saltar este problema, tendre la posibilidad de apagar remotamente mi aplicacion y arrancarla. Al arrancarse se conecta a https://eagora.telefonica.es/portal/site/e-agora/, que es donde salta el Formulario de acceso y entonces tengo que darle a ACEPTAR manualmente, lo cual es un fastidio que hacer a mi aplicacion depender del factor humano. ¿Alguien sabe como solucionar esto?
Una solucion que tengo en mente es mediante un timer esperar a que mi Webbrowser se conecte, esperar unos segundos, y enviar un ENTER mediante Sendkeys, pero esta solucion no solucionó el problema ya que el propio codigo de VB se queda en pausa hasta que haga enter en el Formulario modal que sale. Gracias por vuestra ayuda y espero respuestas o ideas.

Hola, ¿ sos eligioalmuedo no ? vos me comentaste de tu otra cuenta no podias entrar, XR aviso con un post, que los que no tenian un mail en el perfil...al actualizar el foro no podian volver a entrar mas con esa cuenta ¿vos tenias puesto un mail ?

bueno sobre el tema mira, creo que se podria hacer sabiendo donde esta haciendo el metodo POST ese mensaje modal...o sea yo no puedo verlo porque no tengo la contraseña y usuario, pero vos que si la tenes...podes ver con cualquier monitor de GET/POST de un navegador, a que direccion hace el POST, seguro le envia la contraseña y usuario, pero habria que ver que no la envie encriptada.si este metodo funciona, ni tendrias que pasar por mensaje modal ese, directamente pones el link donde hace el POST, pasandole como prametro, el usuario y contraseña...ya te digo que esto seria si no la pasa encriptada o algo parecido.

otra forma que pienso es hacerlo directamente con api's para completar el login, y es mucho mejor que SendKeys, ya que con la sapi's podes enviar el texto directamente a la ventana y sus textbox sabiendo su nombre de clase, y eso no va a fallar nunca, y tambien podes hacer el click al boton mediante api, en otro foro postie como hacer un login al dialogo que aparece cuando uno entra al router...es algo parecido a lo que queres hacer vos.

proba esto, lo arme asi nomas del ejemplo del router, pero debe funcionar, debes poner tu correcto pass y usuario donde corresponde.

Código:

Option Explicit
 
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function SendMessageSTRING Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As String) As Long
Private Declare Function SendMessageLONG Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Long) As Long
 
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_LBUTTONUP = &H202
Private Const WM_SETTEXT = &HC
 
Private Sub Form_Load()
    WebBrowser1.Navigate "https://eagora.telefonica.es/portal/site/e-agora/"
    Timer1.Enabled = True
    Timer1.Interval = 2500
End Sub
 
Private Sub Timer1_Timer()
    Dim a As Long, b As Long, c As Long, d As Long, f As Long, g As Long
    Dim vBoton As Long
 
    a = FindWindow("#32770", vbNullString) 'la ventana padre del login
    b = FindWindowEx(a, 0&, "syscredential", vbNullString) 'el marco oculto
    c = FindWindowEx(b, 0&, "comboboxex32", vbNullString) 'el combo padre
    d = FindWindowEx(c, 0&, "combobox", vbNullString) 'el combo contenedor
    f = FindWindowEx(d, 0&, "edit", vbNullString) 'el textbox del usuario
    g = FindWindowEx(b, 0&, "edit", vbNullString) 'el del password
    vBoton = FindWindowEx(a, 0&, "Button", "Aceptar")
    
    Call SendMessageSTRING(f, WM_SETTEXT, 256, "usuario") 'pones el usuario
    Call SendMessageSTRING(g, WM_SETTEXT, 256, "password") 'pones la contraseña
    
    Call SendMessageLONG(vBoton, WM_LBUTTONDOWN, 0, ByVal 0&)
    Call SendMessageLONG(vBoton, WM_LBUTTONUP, 0, ByVal 0&) 'Apretamos el Boton Aceptar
    
    Timer1.Enabled = False
End Sub

saludos.

Explendida respuesta como siempre Seba. Muchas gracias...una vez mas. La solucion con Apis es perfecta. Funciona correctamente y tan rapido que no da tiempo ni de ver como se escriben en los textbox el usuario y contraseña. Funciona tanto si esta marcado el Check de recordar contraseña como si no. Cuando lo esta sustituye el existente por el que ponemos por codigo. Ahora solo me queda leer de un txt el usuario y pass para hacer dinamico el uso de contraseñas.

En cuanto al POST lo hace encriptado. Fue lo primero que intenté antes de postear en el foro. Uso bastante el TampeIE para capturar enlaces de direcciones para mi aplicacion.

Me viene de perlas esta ayuda, ya que mañana es lunes y podre empezar a controlar el servidor remotamente. Mi objetivo era cerrar la aplicacion servidor cuando se queda colgada desde mi propio PC sin tener que levantarme para hacerlo manualmente. Ahora una pequeña aplicacion estara abierta y a la escucha por winsock a que le ordene que cierre la aplicacion y la vuelva a arrancar. La unica pega que tenia era con el tema del usuario y contraseña que ahora gracias a tu codigo puedo automatizar, con lo que tengo garantizado el reinicio de la aplicacion del servidor de mi empresa. Esto supone no tener que levantarme unas 10 veces diarias a re-arrancar la aplicacion.

Antes de irme dejare aqui el codigo que uso para cerrar una aplicacion y volverla a iniciar, por si a alguien le viene bien esto.

Código:

Private Function MatarProceso(StrNombreProceso As String) As Boolean
 
MatarProceso = False
Set ObjetoWMI = GetObject("winmgmts:")
If IsNull(ObjetoWMI) = False Then
 
   'instanciamos la variable
   Set ListaProcesos = ObjetoWMI.InstancesOf("win32_process")
  
   'Recorremos los procesos buscando el nuestro
   For Each ProcesoACerrar In ListaProcesos
       
       If UCase(ProcesoACerrar.Name) = UCase(StrNombreProceso) Then
          'Matamos el proceso con el método Terminate
          ProcesoACerrar.Terminate (0)
          MatarProceso = True
       End If
       
   Next
End If
  
'Elimina las variables
Set ListaProcesos = Nothing
Set ObjetoWMI = Nothing
End Function

El codigo no es mio. Lo pille en la red.
Ejemplo: MatarProceso ("notepad.exe")
Lo busca en la lista de procesos y la detiene sin mensajes ninguno y con el 100% de efectividad.

El codigo para arrancar una aplicacion es facil con Shell:

Código:

Shell "c:\Kronos.exe", 1

...para arrancar una aplicacion llamada Kronos.exe que se encuentra en esa ruta.

Bueno, no me enrollo mas. Que muchas gracias por tu pronta y efectiva respuesta. Un saludo a todos los foreros desde España-Sevilla