Buenas a todos
Estoy realizando un programa en el cual tengo que trabajar con el plan contable general, hasta ahi todo bien
El problema que en la database tengo unos numeros del plan contable ejemp "1234567890" siempre son 10 digitos , a mostrarlo en un Textbox deberia quedar "123.4.5.67890", he probado de todo y solo consigo que salga en formato numerico, miles, decimales etc..
Gracias

Hola, creo que para conseguir lo que quieres, la solución es crearte un funcion que formatee la salida como tu quieres, por ejemplo esta.

Código:

Private Function ConFormato(Cadena As String) As String
  ConFormato = Replace(Format(Cadena, "000 0 0 00000"), " ", ".")
End Function

Por ejemplo si haces
Cuenta = "1234567890"
Text1.Text = ConFormato(Cuenta)

No puedes utilizar en el formato 000.0.0.00000 porque el . tiene un tratamiento especial, por esto utilizo el truco del Replace para sustituir después del Format el caracter blanco por punto.

Saludos

Que maquina erbuson. Chapó.

Hola Eligio, a esto le llamo yo ser un chapucero, pero mientras las chapuzas funcionen, ¿ para que vamos a complicarnos mas ?

Saludos

Perdona que no comparta tu opinión, pero a dar soluciones a los problemas le llamo yo programar. Recordemos que cada maestrillo tiene su librillo, pero saber solucionar los problemas es la meta. El camino depende del nivel que cada uno tenga. Es evidente que cuanto mas nivel se tiene, mejor estructurado y simple queda el codigo. Pero cuando las cosas no tiene una solucion ortodoxa, la imaginacion no tiene precio. Asi que al Cesar lo que es del Cesar.........CHAPO

Gracias, funciona perfectamente
El otro "problemilla " tambien es sobre la mascara
se trata del CIF, este puede ser con una letra al principio, al final o con ambas

B12345678
12345678K
B12345678K

deberian quedar de esta forma

B-12345678
12345678-K
B-12345678-K

Gracias de nuevo

Hola de nuevo. En este caso se me ocurre que podrías utilizar algo así:

Código:

Private Function FormatoNIF(ByVal Cadena As String) As String
  If Not IsNumeric(Left$(Cadena, 1)) Then Cadena = Left$(Cadena, 1) & "-" & Mid$(Cadena, 2)
  If Not IsNumeric(Right$(Cadena, 1)) Then Cadena = Left$(Cadena, Len(Cadena) - 1) & "-" & Right$(Cadena, 1)
  FormatoNIF = Cadena
End Function

Ten en cuenta que la funcion SOLO comprueba que el primer y/o último caracter no sea numérico y si es así, le añade o precede el guion

O sea, que lo mismo colaria que si se indicase como NIF $123456789&, entonces la rutina te devolvería con el formato: $-123456789-& por lo tanto de ti depende controlar el primero y último caracter, aparte de que evidentemente si indicas mas de una letra, el resultado no será el esperado. BB12345678 devolvera la secuencia B-B12345678

Un saludo

En la direccion: Validar CIF, e leido cosas que no sabia en CIF, y que son interesantes. Eso me ha empujado a crear este codigo que te va a servir para el tema de los guiones.

Código:

'Declaracion de Api para mayusculas
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Const ES_UPPERCASE = &H8&
Const GWL_STYLE = (-16)
Dim aPila

Private Sub Form_Load()

'Aplica la mayuscula al control
Call Aplicar_Mayusculas(Text1)
End Sub

Private Function Aplicar_Mayusculas(ElControl As Control)

'Aplica la API al control para forzar la mayuscula
SetWindowLong ElControl.hWnd, GWL_STYLE, GetWindowLong(ElControl.hWnd, GWL_STYLE) Or ES_UPPERCASE
End Function

Private Sub Text1_Change()

'Variable de control para evitar anidamientos
If aPila = 1 Then Exit Sub

'Evita comprobaciones innecesarias
If Text1 = "" Then Exit Sub

'Comprueba si tiene que poner guion en la primera letra
If Len(Text1) = 1 And InStr("ABCDEFGHKLMNPQS", Mid(Text1, 1, 1)) <> 0 Then
    Text1 = Text1 & "-"
    Text1.SelStart = Len(Text1)
    Exit Sub
End If

'Comprueba si tiene que poner guion en la ultima letra
If InStr("ABCDEFGHIJ", Mid(Text1, Len(Text1), 1)) <> 0 Then
    aPila = 1
    Text1 = Mid(Text1, 1, Len(Text1) - 1) & "-" & Mid(Text1, Len(Text1), 1)
    Text1.SelStart = Len(Text1)
    aPila = 0
    Exit Sub
End If

End Sub

Ademas de usar una API para que el campo Text1 siempre tenga las letras en mayusculas, automatiza los guiones. No he podido probarlo mucho, asi que no te extrañe que tenga alguna laguna que filtrar, pero funciona a priori bastante bien. Le he limitado las letras del CIF a las que por lo visto son las correctas que hay en los CIF correctos.

Erbuson, como ves he tenido que hacer una chapucilla con una variable llamada aPila para impedir que los cambios del Text1 vuelvan a llamar a la sub change. Lo que me desconcierta es que no ocurre cuando pasa por el apartado que controla el primer guion. A ver si le ves tu que puede ser porque no doy con la tecla.

Urpi09, olvide comentar que el codigo lo puedes probar en un nuevo proyecto con un Textbox solamente. Luego tú lo adaptas a tu proyecto para hacerlo correr.

La funcion Aplicar_Mayusculas es una de mis fijas en mis proyectos por lo util que es. Saludos

Hola Eligio:

En mi opinión creo que si debe llamar al Change pero ya no se da ninguna de las dos circunstancias y por ello la sensacion de que no lo hace.

If Len(Text1) = 1 And InStr("ABCDEFGHKLMNPQS", Mid(Text1, 1, 1)) <> 0 Then
Len vale 2 por lo tanto no ejecuta el contenido del If

If InStr("ABCDEFGHIJ", Mid(Text1, Len(Text1), 1)) <> 0 Then
El ultimo caracter es el guion por tanto tampoco ejecuta este If
Creo que es por esto

En cuando al tema de los guiones, personalmente considero que lo hace por un efecto visual ya que para guardar la información, esto no sería correcto. En las declaraciones fiscales, no se admiten guiones, espacios, barras, etc.


Saludos

Efectivamente los guiones son para efecto visual , ya que en la gestoria lo emplean para los listados interno, en la database lo guardo sin guiones