Queria saber si en un msFlexGrid se puede cambiar el orden en el que nuestra los campos ya que los muestra tal y como están en la base de datos y si se puede cambiar el nombre de éstos porque tambien toma el nombre del nombre de campo de la base de datos.

A la primera pregunta: Al cargar la tabla en el recordset le pones "Order by [campo]"


y a la segunda:MSFlexGrid1.TextMatrix(0, 1) = "Columna uno"


Saludos

Gracias Anibal, siempre estás ahí. Creo que no me he explicado bien en mi primera pregunta. La tabla la ordeno por el campo Id ascendentemente, pero yo quiero saber si se puede poner la primera columna del msFlexGrid como segunda o tercera por ejemplo y asi ordenar las columnas como yo quiera y no como aparecen.

El MSFlexGrid, ¿lo tienes conectado a un control Data o a un recordset? ¿En diseño, o por código?


Saludos

Lo tengo conectado a un Data en diseño. El DataBaseName y el DataRecordSource lo estblezco por codigo (por si influye).

Te pongo un ejemplo de cómo conectar un MSFlexGrid a un recordset ADO (mostrando los campos en el orden que quieras) sin necesidad de control Data


[CODE]Option Explicit
Dim rs As ADODB.Recordset
Dim cn As ADODB.Connection


Private Sub Form_Load()
Dim i As Integer

Set cn = New ADODB.Connection
cn.CursorLocation = adUseClient
cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False;" & _
"Data Source=" & App.Path & "\NombreBD.mdb"
Set rs = New ADODB.Recordset

rs.CursorLocation = adUseClient
' en la tabla están por este orden: id, Edad, Apellidos, Nombre
rs.Open "select Nombre, Apellidos, id, Edad from LaTabla order by id", cn, adOpenKeyset, adLockOptimistic
' el recordset los abre en el orden indicado
With MSFlexGrid1
' asignamos el número de columnas igual al nº de campos del recordset
.Cols = rs.Fields.Count
' fila de encabezado, ponemos el nombre de los campos
For i = 0 To .Cols - 1
.TextMatrix(0, i) = rs.Fields(i).Name
Next i
' cargamos el grid con los campos del recorset
rs.MoveFirst
Do Until rs.EOF
.AddItem rs(0) & vbTab & rs(1) & vbTab & rs(2) & vbTab & rs(3)
rs.MoveNext
Loop
End With
End Sub
[CODE]


Espero que te sirva.


Saludos