buenas una pregunta, no puedo saber como es el top y el left de mi formulario pero sin incluir el borde, por ejemplo si yo pongo msgbox me.top
esto me debuelve el top pero del borde del formulario y quiero saver el top del formulario en si, ya prove con GetWindowRect y GetClientRect debuelve lo mismo

Saludos

GetClientRect() te devuelve las dimensiones del area cliente de la ventana, no su posicion en la pantalla, pero si pasas las coordenadas de cliente a coordenadas de pantalla entonces te devuelve la posicion del area de cliente en la pantalla, lo que altera tambien el resultado de la representacion de sus dimensiones (Width + Left, Height + Top). Este ejemplo te muestra como obtener la posicion del area cliente en la pantalla:

Código:

Private Type POINTAPI
 x As Long
 y As Long
End Type

Private Type RECT
 Left As Long
 Top As Long
 Right As Long
 Bottom As Long
End Type

Private Declare Function ClientToScreen Lib "user32.dll" ( _
 ByVal hwnd As Long, _
 ByRef lpPoint As POINTAPI) As Long
Private Declare Function GetClientRect Lib "user32.dll" ( _
 ByVal hwnd As Long, _
 ByRef lpRect As RECT) As Long

Private Sub Form_Load()
 Dim rct As RECT
 Dim pt As POINTAPI
 
 Call GetClientRect(Me.hwnd, rct)
 pt.x = rct.Left
 pt.y = rct.Top
 Call ClientToScreen(Me.hwnd, pt)
 MsgBox "Form.Left = " & (Me.Left / Screen.TwipsPerPixelX) & vbNewLine & _
 "Form.Top = " & (Me.Top / Screen.TwipsPerPixelY) & vbNewLine & _
 "Cliente.Left = " & pt.x & " px" & vbNewLine & _
 "Client.Top = " & pt.y & " px"
End Sub

Lo jodido es cuando quieras posicionar y redimensionar una ventana definiendo las dimensiones del area de cliente y no de la ventana en si, que no veas la que tuve que montar en la dx_lib32 para ello teniendo que obtener los valores de configuracion de barra de titulo, bordes internos y externos, etc... eso tiene mas miga pero tambien solucion

Salu2...

jaja me ganaste justo havia encontrado con ClientToScreen es exactamente como me hacia falta, es que queria llamar a un segundo formulario y posicionarlo en determinado lugar utilizando el codigo x , y del primero y no sabia como, Gracias saludos

Hace unos meses tube el mismo problema que Leandro, tenia que aveirguar el x,y de un control relativo a la pantalla.

Estube como 500 horas, y no me salia, me recorrí todo el apiviewer y na, incluso probé exactamente igual que lo hizo Ex3 con CleinttoScreen
Y como ya estaba tan cansado y no me daban las neuronas ni para sumar 2+2, en la llamada a ClientToScreen, me olvidé de asignar los valores a X, e y ( El pointApi) ( gran detalle )

Código:

pt.x = rct.Left ' me faltó esto
pt.y = rct.Top ' y esto
Call ClientToScreen(Me.hwnd, pt)

Por lo tanto me daba cualquier valor

Terminé solucionandolo igual, pero haciendo una CAHPUZA DE AQUELLAS jej

saludos