Hola espero que esten bien.

Como puedo desaparecer el Popup Menu cuando el mouse se encuentre fuera del boton q lo muestra, automaticamente, no al dar un click, se puede hacer con el API sendmessenger?, espero me haya explicado.

espero me puedan ayudar.
Agradezco de Antemano cualquier comentario

hola fijate algo asi si te sirve

Código:

Option Explicit
Private Declare Function EndMenu Lib "user32.dll" () As Long
Private Declare Function GetCursorPos Lib "user32.dll" (ByRef lpPoint As POINTAPI) As Long
Private Declare Function WindowFromPoint Lib "user32.dll" (ByVal xPoint As Long, ByVal yPoint As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long

Private Type POINTAPI
 x As Long
 y As Long
End Type

Dim hButton As Long

Private Sub Command1_Click()
Timer1.Interval = 100
hButton = Command1.hwnd
PopupMenu mimenu, , Command1.Left, Command1.Top + Command1.Height
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
Timer1.Interval = 100
PopupMenu mimenu
End Sub




Private Sub Timer1_Timer()
 Dim PT As POINTAPI
 Dim hwnd As Long
 GetCursorPos PT
 hwnd = WindowFromPoint(PT.x, PT.y)
 
 If GetWinClassName(hwnd) <> "#32768" And hwnd <> hButton Then
 EndMenu
 Timer1.Interval = 0
 End If
End Sub

Public Function GetWinClassName(hwnd As Long) As String
 Dim sClass As String, ret&
 sClass = Space$(128)
 ret = GetClassName(hwnd, ByVal sClass, 128)
 GetWinClassName = Left$(sClass, ret)
End Function

Saludos

Hola.
Gracias eso es lo que buscaba, mil gracias.

yo intente hacelo igual con el GetCursorpos, mouse_event y el GetRec... no recuerdo que, pero el problema era que si me salia del boton al menu si pasaba el area del boton en el menu mas bien, se desaparacia, pero si eso es lo que queria hacer gracias.

una pregunta para que es esto?
"#32768"

que lo tienes en este if:

If GetWinClassName(hwnd) <> "#32768" And hwnd <> hButton Then
EndMenu
Timer1.Interval = 0
End If

gracias de nuevo

Hola, #32768 es el classname de los menu (almenos en xp y en Vista) no estoy muy seguro en 98.
eso simpre lo podes averiguar con algun tipo de spy, no tengo la direccion de ninguno para pasarte pero en la web hay muchos.

Saludos